<HTML>
<XMP>
# KEHOME/doc/glossary.txt
# Mar/2/2003

#==================#
# MKR/MKE glossary #
#==================#
#=====================================================#
# References (see KEHOME/doc/ref.html)                #
#   Glossary of Objectivist Definitions               #
#   Introduction to Objectivist Epistemology          #
#   Objectivism: The Philosophy of Ayn Rand           #
#   The Ayn Rand Lexicon                              #
#   KEHOME/kb/tabrasa.def                             #
#   KEHOME/kb/ke.def                                  #
#   KEHOME/knowledge/theory/Epistemology/epist.html   #
#   KEHOME/knowledge/theory/Epistemology/identify.htm #
#=====================================================#


#===========================#
# entity and characteristic #
#===========================#

# existent
# An "existent" is something that exists, be it a thing,
# an attribute or an action.

existent isc
	entity,
	characteristic,
	proposition;

# entity
# Since it is axiomatic, the referents of entity can be
# specified only ostensively, by pointing to the things
# given to men in sense perception ... solid things with
# a perceivable shape, such as a rock, a person, or a table.

entity isa existent
	with characteristic;
entity isc
	animal,
	plant,
	object;

# characteristic
# A characteristic is a part of the identity of an entity.

characteristic isa existent
	with identity of entity;
characteristic isc
	part,
	attribute,
	action,
	relation,
	interaction;

# proposition
# A proposition is an identification of a relation(s)
# between entity, characteristic.

proposition isa existent
	with identification of entity, characteristic relation;
proposition isc {
	at context { sentence };
};

 
# context
# The context is the entire field of a mind's awareness
# or knowledge at any level of its cognitive development.

context isa proposition list
	with space, time, view;
context isc
	tabula rasa,
	...;

# sentence
# A sentence is a list of symbols used to represent
# the relations between existents.

sentence isa symbol list
	with subject, predicate, object;
sentence isc
	statement,
	question,
	command,
	assignment;

# word
# A word is merely a visual-auditory symbol used to represent
# a concept.

word isa symbol
	with referent = concept,
	     sensation = visual-auditory;

# meaning
# The meaning of a concept is the existents subsumed
# under the concept.

word means concept;
concept means existent;
sentence means relations between concepts;
proposition means relations between existents;

 
#===========================#
# proposition and knowledge #
#===========================#

at context { sentence };
context has space=s,time=t,view=v;
 
statement isc {
    existent is existent;
    existent has characteristic;
    existent haspart part = partvalue;
    existent has attribute = value; 
    entity do action = event
	with action characteristics
	out  action products
	od   action direct objects
	from initial characteristics
	to   final   characteristics
	done;
    existent:1 rel existent:2;  # relation
    event:1 causes event:2;     # interaction
}

# knowledge
# "Knowledge" is ... a mental grasp of a fact(s) of reality,
# reached either by perceptual observation or by a process
# of reason based on perceptual observation.

percept     := man do perceive od entity         done;
concept     := man do classify od percept        done;
measurement := man do measure  od characteristic done;
proposition := man do identify od entity         done;
definition  := man do define   od concept        done;
proposition := man do reason   od proposition	 done;
knowledge   := man do identify od existent       done;
knowledge   haspart proposition list;

# implicit knowledge
# Implicit knowledge is passively held material which,
# to be grasped, requires a special focus and process
# of consciousness.


#========================#
# concept and definition #
#========================#

# concept
# A concept is a mental integration of two or more units
# possessing the same distinguising characteristic(s),
# with their particular measurements omitted.

concept isa group of two or more units
	with same distinguishing characteristics,
	     particular measurements omitted;
concept isc two or more units;
concept := man do mentally integrate
	od two or more units
	with distinguishing characteristics,
	     particular measurements omitted
	done;
 
# unit
# A unit is an existent regarded as a separate member
# of a group of two or more similar members.

unit isa existent
	with { unit ismem group of two or more similar units; };
unit := man do mentally differentiate
	od concept
	with distinguishing characteristics,
	     particular measurements included 
	done;
 
# definition
# A definition is a statement that identifies the nature
# of the units subsumed under a concept.

definition isa statement with identification of unit, concept relation;
definition isc
	genus-differentia definition,
	ostensive definition,
	procedural definition;
concept isa genus with essential characteristics;
concept isc two or more units;
concept := entity do method ... done;

 
#================================#
# measurement and classification #
#================================#

# measurement
# Measurement is the identification of a relationship --
# a quantitative relationship established by means of a
# standard that serves as a unit.

measurement := entity do measure
		od characteristic of existent
		with standard as unit
		done;

# classification
# Classification is ...

class := entity do classify
	od existent
	with particular measurements
	to concept hierarchy
	done;

</XMP>
</HTML>
